SQLSERVER對加密的存儲過程、視圖、觸發器進行解密(推薦)

加密測試的存儲過程

1. IF EXISTS(SELECT 1 FROM SYSOBJECTS WHERE TYPE='P' AND NAME='P_TEST')
2. DROP PROCEDURE P_TEST
3. GO
4. CREATE PROCEDURE P_TEST(@USERNAME VARCHAR(20),@MSG VARCHAR(20) OUTPUT)
5. WITH ENCRYPTION
6. AS
7. BEGIN
8. IF(SELECT COUNT(1) FROM Custs WHERE NAME=@USERNAME)>0
9. SET @MSG='此用戶名存在'
10. ELSE
11. SET @MSG='此用戶名不存在'
12. END

解密的存儲過程

1. Create PROCEDURE Decryption(@procedure sysname = NULL)
2. AS
3. SET NOCOUNT ON
4. DECLARE @intProcSpace bigint, @t bigint, @maxColID smallint,@procNameLength int
5. select @maxColID = max(subobjid) FROM
6. sys.sysobjvalues WHERE objid = object_id(@procedure)
7. --select @maxColID as 'Rows in sys.sysobjvalues'
8. select @procNameLength = datalength(@procedure) + 29
9. DECLARE @real_01 nvarchar(max)
10. DECLARE @fake_01 nvarchar(max)
11. DECLARE @fake_encrypt_01 nvarchar(max)
12. DECLARE @real_decrypt_01 nvarchar(max),@real_decrypt_01a nvarchar(max)
13. declare @objtype varchar(2),@ParentName nvarchar(max)
14. select @real_decrypt_01a = ''
15. --提取對象的類型如是存儲過程還是函數，如果是觸發器，還要得到其父對象的名稱
16. select @objtype=type,@parentname=object_name(parent_object_id)
17. from sys.objects where [object_id]=object_id(@procedure)
18. -- 從sys.sysobjvalues里提出加密的imageval記錄
19. SET @real_01=(SELECT top 1 imageval FROM sys.sysobjvalues WHERE objid =
20. object_id(@procedure) and valclass = 1 order by subobjid)
21.  
22. --創建一個臨時表
23. create table #output ( [ident] [int] IDENTITY (1, 1) NOT NULL ,
24. [real_decrypt] NVARCHAR(MAX) )
25. --開始一個事務，稍后回滾
26. BEGIN TRAN
27. --更改原始的存儲過程，用短橫線替換
28. if @objtype='P'
29. SET @fake_01='ALTER PROCEDURE '+ @procedure +' WITH ENCRYPTION AS select 1
30. /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 -@procNameLength)+'*/'
31. else if @objtype='FN'
32. SET @fake_01='ALTER FUNCTION '+ @procedure +'() RETURNS INT WITH ENCRYPTION AS BEGIN RETURN 1
33. /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 -@procNameLength)+'*/ END'
34. else if @objtype='V'
35. SET @fake_01='ALTER view '+ @procedure +' WITH ENCRYPTION AS select 1 as col
36. /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 -@procNameLength)+'*/'
37. else if @objtype='TR'
38. SET @fake_01='ALTER trigger '+ @procedure +' ON '+@parentname+'WITH ENCRYPTION AFTER INSERT AS RAISERROR (''N'',16,10)
39. /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 -@procNameLength)+'*/'
40. EXECUTE (@fake_01)
41. --從sys.sysobjvalues里提出加密的假的
42. SET @fake_encrypt_01=(SELECT top 1 imageval FROM sys.sysobjvalues WHERE objid =
43. object_id(@procedure) and valclass = 1 order by subobjid )
44. if @objtype='P'
45. SET @fake_01='Create PROCEDURE '+ @procedure +' WITH ENCRYPTION AS select 1
46. /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 -@procNameLength)+'*/'
47. else if @objtype='FN'
48. SET @fake_01='CREATE FUNCTION '+ @procedure +'() RETURNS INT WITH ENCRYPTION AS BEGIN RETURN 1
49. /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 -@procNameLength)+'*/ END'
50. else if @objtype='V'
51. SET @fake_01='Create view '+ @procedure +' WITH ENCRYPTION AS select 1 as col
52. /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 -@procNameLength)+'*/'
53. else if @objtype='TR'
54. SET @fake_01='Create trigger '+ @procedure +' ON '+@parentname+'WITH ENCRYPTION AFTER INSERT AS RAISERROR (''N'',16,10)
55. /**//*'+REPLICATE(cast('*'as nvarchar(max)), datalength(@real_01) /2 -@procNameLength)+'*/'
56. --開始計數
57. SET @intProcSpace=1
58. --使用字符填充臨時變量
59. SET @real_decrypt_01 = replicate(cast('A'as nvarchar(max)), (datalength(@real_01) /2 ))
60. --循環設置每一個變量，創建真正的變量
61. --每次一個字節
62. SET @intProcSpace=1
63. --如有必要，遍歷每個@real_xx變量并解密
64. WHILE @intProcSpace<=(datalength(@real_01)/2)
65. BEGIN
66. --真的和假的和加密的假的進行異或處理
67. SET @real_decrypt_01 = stuff(@real_decrypt_01, @intProcSpace, 1,
68. NCHAR(UNICODE(substring(@real_01, @intProcSpace, 1)) ^
69. (UNICODE(substring(@fake_01, @intProcSpace, 1)) ^
70. UNICODE(substring(@fake_encrypt_01, @intProcSpace, 1)))))
71. SET @intProcSpace=@intProcSpace+1
72. END
73.  
74.  
75. --通過sp_helptext邏輯向表#output里插入變量
76. insert #output (real_decrypt) select @real_decrypt_01
77. --select real_decrypt AS '#output chek' from #output --測試
78. -- -------------------------------------
79. --開始從sp_helptext提取
80. -- -------------------------------------
81. declare @dbname sysname
82. ,@BlankSpaceAdded int
83. ,@BasePos int
84. ,@CurrentPos int
85. ,@TextLength int
86. ,@LineId int
87. ,@AddOnLen int
88. ,@LFCR int --回車換行的長度
89. ,@DefinedLength int
90. ,@SyscomText nvarchar(max)
91. ,@Line nvarchar(255)
92. Select @DefinedLength = 255
93. SELECT @BlankSpaceAdded = 0 --跟蹤行結束的空格。注意Len函數忽略了多余的空格
94. CREATE TABLE #CommentText
95. (LineId int
96. ,Text nvarchar(255) collate database_default)
97. --使用#output代替sys.sysobjvalues
98. DECLARE ms_crs_syscom CURSOR LOCAL
99. FOR SELECT real_decrypt from #output
100. ORDER BY ident
101. FOR READ ONLY
102. --獲取文本
103. SELECT @LFCR = 2
104. SELECT @LineId = 1
105. OPEN ms_crs_syscom
106. FETCH NEXT FROM ms_crs_syscom into @SyscomText
107. WHILE @@fetch_status >= 0
108. BEGIN
109. SELECT @BasePos = 1
110. SELECT @CurrentPos = 1
111. SELECT @TextLength = LEN(@SyscomText)
112. WHILE @CurrentPos != 0
113. BEGIN
114. --通過回車查找行的結束
115. SELECT @CurrentPos = CHARINDEX(char(13)+char(10), @SyscomText,
116. @BasePos)
117. --如果找到回車
118. IF @CurrentPos != 0
119. BEGIN
120. --如果@Lines的長度的新值比設置的大就插入@Lines目前的內容并繼續
121. While (isnull(LEN(@Line),0) + @BlankSpaceAdded +
122. @CurrentPos-@BasePos + @LFCR) > @DefinedLength
123. BEGIN
124. SELECT @AddOnLen = @DefinedLength-(isnull(LEN(@Line),0) +
125. @BlankSpaceAdded)
126. INSERT #CommentText VALUES
127. ( @LineId,
128. isnull(@Line, N'') + isnull(SUBSTRING(@SyscomText,
129. @BasePos, @AddOnLen), N''))
130. SELECT @Line = NULL, @LineId = @LineId + 1,
131. @BasePos = @BasePos + @AddOnLen, @BlankSpaceAdded = 0
132. END
133. SELECT @Line = isnull(@Line, N'') +
134. isnull(SUBSTRING(@SyscomText, @BasePos, @CurrentPos-@BasePos + @LFCR), N'')
135. SELECT @BasePos = @CurrentPos+2
136. INSERT #CommentText VALUES( @LineId, @Line )
137. SELECT @LineId = @LineId + 1
138. SELECT @Line = NULL
139. END
140. ELSE
141. --如果回車沒找到
142. BEGIN
143. IF @BasePos <= @TextLength
144. BEGIN
145. --如果@Lines長度的新值大于定義的長度
146. While (isnull(LEN(@Line),0) + @BlankSpaceAdded +
147. @TextLength-@BasePos+1 ) > @DefinedLength
148. BEGIN
149. SELECT @AddOnLen = @DefinedLength -
150. (isnull(LEN(@Line),0) + @BlankSpaceAdded)
151. INSERT #CommentText VALUES
152. ( @LineId,
153. isnull(@Line, N'') + isnull(SUBSTRING(@SyscomText,
154. @BasePos, @AddOnLen), N''))
155. SELECT @Line = NULL, @LineId = @LineId + 1,
156. @BasePos = @BasePos + @AddOnLen, @BlankSpaceAdded =
157. 0
158. END
159. SELECT @Line = isnull(@Line, N'') +
160. isnull(SUBSTRING(@SyscomText, @BasePos, @TextLength-@BasePos+1 ), N'')
161. if LEN(@Line) < @DefinedLength and charindex(' ',
162. @SyscomText, @TextLength+1 ) > 0
163. BEGIN
164. SELECT @Line = @Line + ' ', @BlankSpaceAdded = 1
165. END
166. END
167. END
168. END
169. FETCH NEXT FROM ms_crs_syscom into @SyscomText
170. END
171. IF @Line is NOT NULL
172. INSERT #CommentText VALUES( @LineId, @Line )
173. select Text from #CommentText order by LineId
174. CLOSE ms_crs_syscom
175. DEALLOCATE ms_crs_syscom
176. DROP TABLE #CommentText
177. -- -------------------------------------
178. --結束從sp_helptext提取
179. -- -------------------------------------
180. --刪除用短橫線創建的存儲過程并重建原始的存儲過程
181. ROLLBACK TRAN
182. DROP TABLE #output
183. GO
184. 啟用DAC
185. SP_CONFIGURE 'remote admin connections';
186. GO
187. ----0：僅允許本地連接使用 DAC，1：允許遠程連接使用 DAC
188. SP_CONFIGURE 'remote admin connections', 0;
189. GO
190. RECONFIGURE WITH OVERRIDE;
191. GO

文件——>新建——>數據庫引擎查詢

服務器名稱：admin:.或者admin:服務器名稱

登錄進去執行解密操作

1. USE TEST
2. EXEC Decryption P_TEST
3. GO

為了安全起見，不要在正式環境進行解密，避免在解密過程中將原存儲過程損壞！

總結

以上所述是小編給大家介紹的SQLSERVER對加密的存儲過程、視圖、觸發器進行解密，希望對大家有所幫助，如果大家有任何疑問請給我留言，小編會及時回復大家的。在此也非常感謝大家對我們網站的支持！